Posted by

Posted on

June 5, 2026

Posted under

Core

Comments

SQL Server 2025 Series : OPTIMIZED_SP_EXECUTESQL — End the Compilation Storm Killing SQL Performance

When dozens of threads hit the same query simultaneously on a cold cache, SQL Server compiles the same plan over and over — burning CPU, wasting resources, and degrading throughput right when your system is most vulnerable. This is a compilation storm, and SQL Server 2025 has a one-line fix for it.

What is a compilation storm?

Every query needs a compiled execution plan before SQL Server can run it. Plans are cached — but when the cache is cold (after a restart, failover, or deployment) and many threads fire the same query at once, each thread independently compiles the same plan:

Comparison of SQL execution performance with and without optimized sp_executeSQL, illustrating cache misses and hits across multiple threads.

One thread pays the compilation cost. Everyone else waits a millisecond and reuses for free.

Step-by-step demo script

The full script below walks through all 10 steps end to end. Run each section in order.

1) Create the database and tables

Sets up jbexecute with Customers, Products, Orders, and a CompilationMetrics table to store before/after results.

			
USE master;
GO
IF EXISTS (SELECT 1 FROM sys.databases WHERE name = N'jbexecute')
BEGIN
    ALTER DATABASE jbexecute SET SINGLE_USER WITH ROLLBACK IMMEDIATE;
    DROP DATABASE jbexecute;
END
GO
CREATE DATABASE jbexecute;
GO
ALTER DATABASE jbexecute SET RECOVERY SIMPLE;
GO
USE jbexecute;
GO
CREATE TABLE dbo.Customers
(
    CustomerID   INT           NOT NULL IDENTITY(1,1) PRIMARY KEY,
    FirstName    NVARCHAR(50)  NOT NULL,
    LastName     NVARCHAR(50)  NOT NULL,
    Email        NVARCHAR(100) NOT NULL,
    Region       NVARCHAR(30)  NOT NULL,
    CreatedDate  DATETIME2     NOT NULL DEFAULT SYSUTCDATETIME()
);
GO
CREATE TABLE dbo.Products
(
    ProductID    INT            NOT NULL IDENTITY(1,1) PRIMARY KEY,
    ProductName  NVARCHAR(100)  NOT NULL,
    Category     NVARCHAR(50)   NOT NULL,
    UnitPrice    DECIMAL(10,2)  NOT NULL,
    StockQty     INT            NOT NULL DEFAULT 1000
);
GO
CREATE TABLE dbo.Orders
(
    OrderID      INT            NOT NULL IDENTITY(1,1) PRIMARY KEY,
    CustomerID   INT            NOT NULL REFERENCES dbo.Customers(CustomerID),
    ProductID    INT            NOT NULL REFERENCES dbo.Products(ProductID),
    Quantity     INT            NOT NULL,
    TotalAmount  DECIMAL(12,2)  NOT NULL,
    OrderStatus  NVARCHAR(20)   NOT NULL DEFAULT N'Pending',
    OrderDate    DATETIME2      NOT NULL DEFAULT SYSUTCDATETIME()
);
GO
CREATE TABLE dbo.CompilationMetrics
(
    MetricID         INT           NOT NULL IDENTITY(1,1) PRIMARY KEY,
    Phase            NVARCHAR(10)  NOT NULL,
    CapturedAt       DATETIME2     NOT NULL DEFAULT SYSUTCDATETIME(),
    CompileEvents    INT           NOT NULL,
    TotalDurationNs  BIGINT        NOT NULL,
    TotalDurationMs  AS (TotalDurationNs / 1000000.),
    Notes            NVARCHAR(500) NULL
);

		

2) Seed sample Data

200 customers, 50 products, 5,000 orders.

			
;WITH cte AS
(
    SELECT TOP 200 ROW_NUMBER() OVER (ORDER BY (SELECT NULL)) AS n
    FROM sys.all_columns a CROSS JOIN sys.all_columns b
)
INSERT INTO dbo.Customers (FirstName, LastName, Email, Region)
SELECT
    N'FirstName' + CAST(n AS NVARCHAR(10)),
    N'LastName'  + CAST(n AS NVARCHAR(10)),
    N'user'      + CAST(n AS NVARCHAR(10)) + N'@shop.com',
    CHOOSE((n % 5) + 1, N'North', N'South', N'East', N'West', N'Central')
FROM cte;
GO
;WITH cte AS
(
    SELECT TOP 50 ROW_NUMBER() OVER (ORDER BY (SELECT NULL)) AS n
    FROM sys.all_columns
)
INSERT INTO dbo.Products (ProductName, Category, UnitPrice, StockQty)
SELECT
    N'Product_' + CAST(n AS NVARCHAR(10)),
    CHOOSE((n % 6) + 1,
        N'Electronics', N'Clothing', N'Books',
        N'Home & Garden', N'Sports', N'Toys'),
    CAST((n * 7.99) AS DECIMAL(10,2)),
    500 + (n * 10)
FROM cte;
GO
;WITH cte AS
(
    SELECT TOP 5000 ROW_NUMBER() OVER (ORDER BY (SELECT NULL)) AS n
    FROM sys.all_columns a CROSS JOIN sys.all_columns b
)
INSERT INTO dbo.Orders (CustomerID, ProductID, Quantity, TotalAmount, OrderStatus)
SELECT
    (n % 200) + 1,
    (n % 50)  + 1,
    (n % 10)  + 1,
    CAST(((n % 50) + 1) * 7.99 * ((n % 10) + 1) AS DECIMAL(12,2)),
    CHOOSE((n % 4) + 1, N'Pending', N'Shipped', N'Delivered', N'Cancelled')
FROM cte;

		

3) Set feature OFF and create Extended Events session

Captures query_post_compilation_showplan (compilation time) and sql_batch_completed (execution) to an .xel file.

			
-- Disable for BEFORE test
ALTER DATABASE SCOPED CONFIGURATION
    SET ASYNC_STATS_UPDATE_WAIT_AT_LOW_PRIORITY = OFF;
ALTER DATABASE SCOPED CONFIGURATION
    SET OPTIMIZED_SP_EXECUTESQL = OFF;
GO
USE master;
GO
IF EXISTS (SELECT 1 FROM sys.server_event_sessions WHERE name = N'Demo_CompilationStorm')
    DROP EVENT SESSION Demo_CompilationStorm ON SERVER;
GO
CREATE EVENT SESSION [Demo_CompilationStorm] ON SERVER
ADD EVENT sqlserver.query_post_compilation_showplan
(
    ACTION
    (
        sqlserver.sql_text,
        sqlserver.database_name,
        sqlserver.client_app_name,
        sqlserver.session_id
    )
    WHERE ([sqlserver].[database_name] = N'jbexecute')
),
ADD EVENT sqlserver.sql_batch_completed
(
    ACTION (sqlserver.sql_text, sqlserver.database_name)
    WHERE  ([sqlserver].[database_name] = N'jbexecute' AND [duration] > 0)
)
ADD TARGET package0.event_file
(
    SET filename         = N'C:\temp\JBExecute\Demo_CompilationStorm.xel',
        max_file_size    = 1024,
        max_rollover_files = 5
)
WITH (MAX_DISPATCH_LATENCY = 5 SECONDS, TRACK_CAUSALITY = ON);
GO
ALTER EVENT SESSION [Demo_CompilationStorm] ON SERVER STATE = START;
GO

		

4) Create the workload file (workload.sql)

Save this as a .sql file. It is what ostress will fire on every thread and iteration.

			
DECLARE @custID  INT;
DECLARE @prodID  INT;
DECLARE @qty     INT;
DECLARE @amount  DECIMAL(12,2);
DECLARE @status  NVARCHAR(20);
DECLARE @sql     NVARCHAR(MAX);
DECLARE @params  NVARCHAR(MAX);
SET @sql = N'
    INSERT INTO dbo.Orders (CustomerID, ProductID, Quantity, TotalAmount, OrderStatus)
    VALUES (@cid, @pid, @qty, @amt, @stat);
    UPDATE dbo.Products
    SET    StockQty = StockQty - @qty
    WHERE  ProductID = @pid AND StockQty >= @qty;
    SELECT o.OrderID,
           c.FirstName + '' '' + c.LastName AS CustomerName,
           p.ProductName,
           o.Quantity,
           o.TotalAmount,
           o.OrderStatus
    FROM   dbo.Orders  o
    JOIN   dbo.Customers c ON c.CustomerID = o.CustomerID
    JOIN   dbo.Products  p ON p.ProductID  = o.ProductID
    WHERE  o.CustomerID = @cid
    ORDER  BY o.OrderDate DESC;
';
SET @params = N'@cid INT, @pid INT, @qty INT, @amt DECIMAL(12,2), @stat NVARCHAR(20)';
SET @custID = (ABS(CHECKSUM(NEWID())) % 200) + 1;
SET @prodID = (ABS(CHECKSUM(NEWID())) % 50)  + 1;
SET @qty    = (ABS(CHECKSUM(NEWID())) % 5)   + 1;
SET @amount = CAST(@prodID * 7.99 * @qty AS DECIMAL(12,2));
SET @status = N'Pending';
EXEC sp_executesql @sql, @params,
     @cid = @custID, @pid = @prodID, @qty = @qty,
     @amt = @amount, @stat = @status;

		

5) Run BEFORE workload with ostress

Clear the plan cache first. Demo servers only. Then fire ostress.

			
-- Clear plan cache (DEMO SERVER ONLY)
ALTER DATABASE SCOPED CONFIGURATION CLEAR PROCEDURE_CACHE;
GO
-- Run from command prompt:
-- ostress -S"YOUR_SERVER" -E -i"C:\temp\JBExecute\workload.sql" -n100 -r5 -q -djbexecute
ALTER EVENT SESSION [Demo_CompilationStorm] ON SERVER STATE = STOP;
GO
WAITFOR DELAY '00:00:05';

		

6) Capture and save BEFORE metrics

Reads the .xel file and stores compile event count and total compile duration into CompilationMetrics.

			
USE jbexecute;
GO
;WITH events AS
(
    SELECT
        n.value('(@name)[1]',                               'NVARCHAR(100)') AS event_name,
        n.value('(data[@name="duration"]/value)[1]',        'BIGINT')        AS duration_ns,
        n.value('(action[@name="database_name"]/value)[1]', 'NVARCHAR(128)') AS db_name
    FROM
    (
        SELECT CAST(event_data AS XML) AS event_xml
        FROM   sys.fn_xe_file_target_read_file(
                   N'C:\temp\JBExecute\Demo_CompilationStorm*.xel',
                   NULL, NULL, NULL)
    ) src
    CROSS APPLY src.event_xml.nodes('//event') AS t(n)
)
SELECT
    'BEFORE (No Feature)'   AS Phase,
    event_name,
    COUNT(*)                AS CompileEventCount,
    SUM(duration_ns)        AS TotalDuration_ns,
    SUM(duration_ns) / 1000000. AS TotalDuration_ms,
    AVG(duration_ns)        AS AvgDuration_ns,
    MAX(duration_ns)        AS MaxDuration_ns
FROM   events
WHERE  event_name = 'query_post_compilation_showplan'
AND    db_name    = 'jbexecute'
GROUP BY event_name;
-- Save to metrics table
;WITH events AS
(
    SELECT
        n.value('(@name)[1]',                        'NVARCHAR(100)') AS event_name,
        n.value('(data[@name="duration"]/value)[1]', 'BIGINT')        AS duration_ns
    FROM
    (
        SELECT CAST(event_data AS XML) AS event_xml
        FROM   sys.fn_xe_file_target_read_file(
                   N'C:\temp\JBExecute\Demo_CompilationStorm*.xel',
                   NULL, NULL, NULL)
    ) src
    CROSS APPLY src.event_xml.nodes('//event') AS t(n)
)
INSERT INTO dbo.CompilationMetrics (Phase, CompileEvents, TotalDurationNs, Notes)
SELECT
    'BEFORE',
    COUNT(*),
    ISNULL(SUM(duration_ns), 0),
    'SQL Server without Optimized sp_executesql — concurrent compilation storm'
FROM   events
WHERE  event_name = 'query_post_compilation_showplan';

		

7) Enable OPTIMIZED_SP_EXECUTESQL

One line. No downtime. No application changes.

			
USE jbexecute;
GO
ALTER DATABASE SCOPED CONFIGURATION
    SET ASYNC_STATS_UPDATE_WAIT_AT_LOW_PRIORITY = ON;
ALTER DATABASE SCOPED CONFIGURATION
    SET OPTIMIZED_SP_EXECUTESQL = ON;
GO
-- Verify
SELECT name, value, value_for_secondary
FROM sys.database_scoped_configurations
WHERE name IN (N'OPTIMIZED_SP_EXECUTESQL',
               N'ASYNC_STATS_UPDATE_WAIT_AT_LOW_PRIORITY');
GO
-- Fresh start for AFTER test
ALTER DATABASE SCOPED CONFIGURATION CLEAR PROCEDURE_CACHE;
GO
ALTER EVENT SESSION [Demo_CompilationStorm] ON SERVER STATE = STOP;
GO
ALTER EVENT SESSION [Demo_CompilationStorm] ON SERVER STATE = START;
GO
-- Run ostress again with identical parameters, then:
ALTER EVENT SESSION [Demo_CompilationStorm] ON SERVER STATE = STOP;
GO
WAITFOR DELAY '00:00:05';

		

8) Capture and save AFTER metrics

			
USE jbexecute;
GO
;WITH events AS
(
    SELECT
        n.value('(@name)[1]',                               'NVARCHAR(100)') AS event_name,
        n.value('(data[@name="duration"]/value)[1]',        'BIGINT')        AS duration_ns,
        n.value('(action[@name="database_name"]/value)[1]', 'NVARCHAR(128)') AS db_name
    FROM
    (
        SELECT CAST(event_data AS XML) AS event_xml
        FROM   sys.fn_xe_file_target_read_file(
                   N'C:\Temp\JBExecute\Demo_CompilationStorm*.xel',
                   NULL, NULL, NULL)
    ) src
    CROSS APPLY src.event_xml.nodes('//event') AS t(n)
)
SELECT
    'AFTER (Optimized sp_executesql ON)' AS Phase,
    event_name,
    COUNT(*)                             AS CompileEventCount,
    SUM(duration_ns)                     AS TotalDuration_ns,
    SUM(duration_ns) / 1000000.          AS TotalDuration_ms,
    AVG(duration_ns)                     AS AvgDuration_ns,
    MAX(duration_ns)                     AS MaxDuration_ns
FROM   events
WHERE  event_name = 'query_post_compilation_showplan'
AND    db_name    = 'jbexecute'
GROUP BY event_name;
;WITH events AS
(
    SELECT
        n.value('(@name)[1]',                        'NVARCHAR(100)') AS event_name,
        n.value('(data[@name="duration"]/value)[1]', 'BIGINT')        AS duration_ns
    FROM
    (
        SELECT CAST(event_data AS XML) AS event_xml
        FROM   sys.fn_xe_file_target_read_file(
                   N'C:\Temp\JBExecute\Demo_CompilationStorm*.xel',
                   NULL, NULL, NULL)
    ) src
    CROSS APPLY src.event_xml.nodes('//event') AS t(n)
)
INSERT INTO dbo.CompilationMetrics (Phase, CompileEvents, TotalDurationNs, Notes)
SELECT
    'AFTER',
    COUNT(*),
    ISNULL(SUM(duration_ns), 0),
    'SQL Server 2025 with OPTIMIZED_SP_EXECUTESQL = ON — serialized compilation'
FROM   events
WHERE  event_name = 'query_post_compilation_showplan';

		

9) Compare before vs after

Shows compile event count, total compile duration, and average compile time per event — all with % reduction.

			
-- Phase detail
SELECT
    Phase, CapturedAt, CompileEvents,
    TotalDurationNs, TotalDurationMs AS TotalDuration_ms,
    CASE WHEN Phase = 'BEFORE'
         THEN 'Baseline — N compilations per burst'
         ELSE 'Optimized — 1 compilation per unique batch'
    END AS Description, Notes
FROM dbo.CompilationMetrics
ORDER BY MetricID;
-- Reduction summary
SELECT
    b.CompileEvents                   AS BEFORE_CompileEvents,
    a.CompileEvents                   AS AFTER_CompileEvents,
    b.CompileEvents - a.CompileEvents AS Compilations_Saved,
    CAST(100.0 * (b.CompileEvents - a.CompileEvents)
         / NULLIF(b.CompileEvents, 0) AS DECIMAL(5,1)) AS Compilations_Pct_Reduction,
    b.TotalDurationMs                 AS BEFORE_TotalCompileDuration_ms,
    a.TotalDurationMs                 AS AFTER_TotalCompileDuration_ms,
    b.TotalDurationMs - a.TotalDurationMs AS CompileDuration_ms_Saved,
    CAST(100.0 * (b.TotalDurationMs - a.TotalDurationMs)
         / NULLIF(b.TotalDurationMs, 0) AS DECIMAL(5,1)) AS CompileDuration_Pct_Reduction,
    CASE WHEN b.CompileEvents > 0
         THEN b.TotalDurationNs / b.CompileEvents END   AS BEFORE_AvgCompile_ns,
    CASE WHEN a.CompileEvents > 0
         THEN a.TotalDurationNs / a.CompileEvents END   AS AFTER_AvgCompile_ns,
    CASE WHEN b.CompileEvents > 0 AND a.CompileEvents > 0
         THEN (b.TotalDurationNs / b.CompileEvents)
            - (a.TotalDurationNs / a.CompileEvents) END AS AvgCompile_ns_Saved,
    CAST(
        100.0 *
        ( (b.TotalDurationNs / NULLIF(b.CompileEvents, 0))
        - (a.TotalDurationNs / NULLIF(a.CompileEvents, 0)) )
        / NULLIF(b.TotalDurationNs / NULLIF(b.CompileEvents, 0), 0)
        AS DECIMAL(5,1))                                AS AvgCompile_Pct_Reduction
FROM
    (SELECT TOP 1 * FROM dbo.CompilationMetrics WHERE Phase = 'BEFORE' ORDER BY MetricID DESC) b
    CROSS JOIN
    (SELECT TOP 1 * FROM dbo.CompilationMetrics WHERE Phase = 'AFTER'  ORDER BY MetricID DESC) a;
GO

		

10) Cleanup

			
ALTER EVENT SESSION [Demo_CompilationStorm] ON SERVER STATE = STOP;
DROP EVENT SESSION [Demo_CompilationStorm] ON SERVER;
GO
USE master;
ALTER DATABASE jbexecute SET SINGLE_USER WITH ROLLBACK IMMEDIATE;
DROP DATABASE jbexecute;
GO

		

Things to know before enabling in production

SQL Server 2025 only. OPTIMIZED_SP_EXECUTESQL is not available on 2022 or earlier. ASYNC_STATS_UPDATE_WAIT_AT_LOW_PRIORITY is available from 2022 onwards.
Waiting threads add latency. Non-first threads wait for the compiling thread. Negligible in most cases — but test carefully if you have genuinely slow-compiling queries.
sp_executesql only. Ad-hoc SQL, stored procedures, and batches where the SQL text varies between calls are not covered by this feature.
Does not fix bad plans. This serializes compilation — it does not improve plan quality. Use Query Store for plan stability alongside this.
Test before production. Validate with Extended Events as shown in this demo. Every workload is different.

Watch the Full Demo

I’ve recorded a complete walkthrough of this setup on my YouTube channel JBSWiki. If you’re a visual learner, go check it out!

👉 Watch here: https://www.youtube.com/watch?v=3BF9wn_IXWQ

Thank You,

Thank You,
Vivek Janakiraman

Disclaimer:
The views expressed on this blog are mine alone and do not reflect the views of my company or anyone else. All postings on this blog are provided “AS IS” with no warranties, and confers no rights.

Posted by

Vivek Janakiraman

Posted on

June 4, 2026

Posted under

Core

Comments

SQL Server 2025 Series : This New Locking Feature Changes Everything – Full Demo on Optimized Locking!

If you work with high-concurrency OLTP workloads, SQL Server 2025 Optimized Locking is one of the most practical improvements to understand. In this demo, we use two databases: one with optimized locking disabled and one with it enabled. Both databases are configured with Accelerated Database Recovery (ADR) and Read Committed Snapshot Isolation (RCSI), while only one database has OPTIMIZED_LOCKING = ON.

Why this feature matters

The real value of optimized locking is simple: it helps reduce lock footprint during write activity, which can lower blocking in busy systems. The attached demo is designed exactly for that comparison by creating two identical databases—Billing_OFF and Billing_ON—and toggling only the optimized locking setting between them.

Demo setup

Start by creating the two demo databases and enabling the required database options:

			
USE master;
GO
DROP DATABASE IF EXISTS Billing_OFF;
DROP DATABASE IF EXISTS Billing_ON;
GO
CREATE DATABASE Billing_OFF;
CREATE DATABASE Billing_ON;
GO
-- Both databases need ADR enabled
ALTER DATABASE Billing_OFF SET ACCELERATED_DATABASE_RECOVERY = ON;
ALTER DATABASE Billing_ON SET ACCELERATED_DATABASE_RECOVERY = ON;
GO
-- RCSI is needed for lock-after-qualification (LAQ) demo
ALTER DATABASE Billing_OFF SET READ_COMMITTED_SNAPSHOT ON WITH ROLLBACK IMMEDIATE;
ALTER DATABASE Billing_ON SET READ_COMMITTED_SNAPSHOT ON WITH ROLLBACK IMMEDIATE;
GO
-- Only one database gets optimized locking
ALTER DATABASE Billing_OFF SET OPTIMIZED_LOCKING = OFF;
ALTER DATABASE Billing_ON SET OPTIMIZED_LOCKING = ON;
GO
-- Verify settings
SELECT
    name,
    is_accelerated_database_recovery_on,
    is_read_committed_snapshot_on,
    is_optimized_locking_on
FROM sys.databases
WHERE name IN ('Billing_OFF', 'Billing_ON');
GO

		

Build the test table

Next, create the same table in both databases and open a transaction so you can inspect locks while the transaction is still active.

Setup for optimized locking OFF

			
USE Billing_OFF;
GO
DROP TABLE IF EXISTS dbo.InvoiceLedger;
GO
CREATE TABLE dbo.InvoiceLedger
(
    InvoiceId int NOT NULL,
    AmountDue decimal(10,2) NULL
);
GO
INSERT INTO dbo.InvoiceLedger (InvoiceId, AmountDue)
VALUES (1001, 1200.00),
       (1002, 850.00),
       (1003, 430.00);
GO
BEGIN TRAN;
UPDATE dbo.InvoiceLedger
SET AmountDue = AmountDue + 50.00;
SELECT
    request_session_id,
    resource_type,
    request_mode,
    resource_description
FROM sys.dm_tran_locks
WHERE request_session_id = @@SPID
  AND resource_type IN ('PAGE', 'RID', 'KEY', 'XACT')
ORDER BY resource_type, request_mode;
-- Keep transaction open for observation
WAITFOR DELAY '00:00:20';
COMMIT TRAN;
GO

		

This script updates all rows and keeps the transaction open for 20 seconds so you can inspect the acquired locks in the Billing_OFF database.

Setup for optimized locking ON

			
USE Billing_ON;
GO
DROP TABLE IF EXISTS dbo.InvoiceLedger;
GO
CREATE TABLE dbo.InvoiceLedger
(
    InvoiceId int NOT NULL,
    AmountDue decimal(10,2) NULL
);
INSERT INTO dbo.InvoiceLedger (InvoiceId, AmountDue)
VALUES (1001, 1200.00),
       (1002, 850.00),
       (1003, 430.00);
GO
BEGIN TRAN;
UPDATE dbo.InvoiceLedger
SET AmountDue = AmountDue + 50.00;
SELECT
    request_session_id,
    resource_type,
    request_mode,
    resource_description
FROM sys.dm_tran_locks
WHERE request_session_id = @@SPID
  AND resource_type IN ('PAGE', 'RID', 'KEY', 'XACT')
ORDER BY resource_type, request_mode;
WAITFOR DELAY '00:00:20';
COMMIT TRAN;
GO

		

This is the matching script for Billing_ON, allowing you to compare lock behavior when optimized locking is enabled.

Concurrency test

To demonstrate blocking behavior, open two sessions against each database.

Session 1 – hold an update open

Optimized locking OFF

			
USE Billing_OFF;
GO
BEGIN TRAN;
UPDATE dbo.InvoiceLedger
SET AmountDue = AmountDue + 25.00
WHERE InvoiceId = 1001;
WAITFOR DELAY '00:00:20';
COMMIT TRAN;
GO

		

This session updates InvoiceId = 1001 and intentionally holds the transaction for 20 seconds.

Optimized locking ON

			
USE Billing_ON;
GO
BEGIN TRAN;
UPDATE dbo.InvoiceLedger
SET AmountDue = AmountDue + 25.00
WHERE InvoiceId = 1001;
WAITFOR DELAY '00:00:20';
COMMIT TRAN;
GO

		

This is the same workload pattern, but executed in the database where optimized locking is enabled.

Session 2 – concurrent update

Optimized locking OFF

			
USE Billing_OFF;
GO
BEGIN TRAN;
UPDATE dbo.InvoiceLedger
SET AmountDue = AmountDue + 25.00
WHERE InvoiceId = 1002;
COMMIT TRAN;
GO

		

Run this in a second session while Session 1 is still open.

Optimized locking ON

			
USE Billing_ON;
GO
BEGIN TRAN;
UPDATE dbo.InvoiceLedger
SET AmountDue = AmountDue + 25.00
WHERE InvoiceId = 1002;
COMMIT TRAN;
GO

		

Again, this is the same concurrent update, but without optimized locking.

Monitoring script

Use the following monitoring query to observe waits, request state, and lock information for both sessions while the demo is running:

			
-- Replace the session IDs below with the two session IDs used in your demo windows.
SELECT
    r.session_id,
    r.status,
    r.command,
    r.wait_type,
    r.wait_time,
    r.wait_resource,
    t.text
FROM sys.dm_exec_requests r
CROSS APPLY sys.dm_exec_sql_text(r.sql_handle) t
WHERE r.session_id IN (62, 171);
GO
SELECT
    request_session_id,
    resource_type,
    request_mode,
    request_status,
    resource_description
FROM sys.dm_tran_locks
WHERE request_session_id IN (62, 171)
ORDER BY request_session_id, resource_type, request_mode;
GO

		

Expected takeaway

The demo is structured to show that the same update workload behaves differently depending on whether OPTIMIZED_LOCKING is OFF or ON. Because both environments are identically configured except for the optimized locking setting, any change in observed lock behavior is attributable to that feature.

Final thoughts

SQL Server 2025 Optimized Locking is not just a checkbox feature—it directly changes how you demonstrate concurrency, lock management, and blocking reduction to customers. If you want a clean live demo, the attached billing scripts are perfect because they isolate the feature clearly and make the before-vs-after comparison easy to explain.

Watch the Full Demo

I’ve recorded a complete walkthrough of this setup on my YouTube channel JBSWiki. If you’re a visual learner, go check it out!

👉 Watch here: https://www.youtube.com/watch?v=-XQj5YtnuEY

Thank You,
Vivek Janakiraman

JBs Wiki

Tag Archives: SQL Server OLTP performance

SQL Server 2025 Series : OPTIMIZED_SP_EXECUTESQL — End the Compilation Storm Killing SQL Performance

What is a compilation storm?

Step-by-step demo script

Things to know before enabling in production

Watch the Full Demo

SQL Server 2025 Series : This New Locking Feature Changes Everything – Full Demo on Optimized Locking!

Why this feature matters

Demo setup

Build the test table

Setup for optimized locking OFF

Setup for optimized locking ON

Concurrency test

Session 1 – hold an update open

Optimized locking OFF

Optimized locking ON

Session 2 – concurrent update

Optimized locking OFF

Optimized locking ON

Monitoring script

Expected takeaway

Final thoughts

Watch the Full Demo