Availability Group – SQL Server Agent Job to run only on Always On Primary Replica

-> I had a requirement to execute jobs only in primary replica.

-> To all jobs that should only be executed on Always On primary replica. I added 1 step as the first step of the job and another step as last step of that job.

-> 1st step of these jobs should execute below TSQL Query,

if (select
ars.role_desc
from sys.dm_hadr_availability_replica_states ars
inner join sys.availability_groups ag
on ars.group_id = ag.group_id
where ag.name = ''
and ars.is_local = 1) = 'PRIMARY'
begin
Print 'This is Primary Replica'
end
else
begin
RAISERROR('This job should not run in Secondary',16,1)
end

-> For 1st step,

On success action : Go to the next step
On failure action: Go to step: [n] Last_Step ( It should basically go to the last step)

-> Last step of the job should execute the below TSQL,

print 'Job_Completion'

-> For Last step,

On success action : Quit the job reporting Success
On failure action: Quit the job reporting failure

Thank You,
Vivek Janakiraman

Disclaimer:
The views expressed on this blog are mine alone and do not reflect the views of my company or anyone else. All postings on this blog are provided “AS IS” with no warranties, and confers no rights.

Database Backup and Maintenance job to use secondary replica on a SQL Instance with Always On Availability group

Environment

Backup_Setup.PNG

Requirement

-> Database backup should happen on secondary replica.
-> Integrity checks should happen on secondary replica.

Alwayson Availability Group Backup Preference Setting

Backup_Preference.png

Solution

-> We will be using Ola Hallengren’s SQL Server Maintenance Solutions.

-> Execute Maintenance.sql on SQL Server Instance JBSERVER1 and JBSERVER2.

-> On JBSERVER1 modify SQL Server Agent job that performs User Database – Full backup to execute below,

 	EXECUTE [dbo].[DatabaseBackup]
	@Databases = 'USER_DATABASES', -- All User DB's included
	@Directory = 'G:\SQL\BACKUP',  -- Database backup Location
	@CopyOnly='Y', -- Copy only backups
	@BackupType = 'FULL', -- Full database backup
	@Verify = 'Y', -- Verify database backup set to YES
	@CleanupTime = 74, -- Cleanup time of 74 Hours
	@CheckSum = 'Y',@LogToTable = 'Y'

-> On JBSERVER1 modify SQL Server Agent job that performs User Database – Log backup to execute below,

	EXECUTE [dbo].[DatabaseBackup]
	@Databases = 'USER_DATABASES', -- All Appropriate User DB's included
	@Directory = 'G:\SQL\BACKUP',  -- Database backup Location
	@BackupType = 'LOG',-- Log Backups
	@Verify = 'Y', -- Verify database backup set to YES
	@CleanupTime = 74, -- Cleanup time of 74 Hours
	@CheckSum = 'Y',@LogToTable = 'Y'

-> On JBSERVER1 modify SQL Server Agent job that performs User Database – Integrity Check to execute below,

	EXECUTE [dbo].[DatabaseIntegrityCheck]
	@Databases = 'USER_DATABASES', -- All User DB's included
	@AvailabilityGroupReplicas='PREFERRED_BACKUP_REPLICA', -- Preferred backup replica will be checked
        @LogToTable = 'Y'

-> Script the modified jobs in JBSERVER1 and create them on JBSERVER2 also.

-> Try executing each job and make sure the backups and Integrity checks are running on the secondary replica. Check the backup file location and also CommandLog table to confirm.

Thank You,
Vivek Janakiraman

Disclaimer:
The views expressed on this blog are mine alone and do not reflect the views of my company or anyone else. All postings on this blog are provided “AS IS” with no warranties, and confers no rights.

Adding Transparent Data Encryption (TDE) Enabled User Database to Always On Availability Group

Environment

TDE_Blog.PNG

Enabling TDE on JBSERVER1


	--Create database JB_DB

	create database JB_DB
	go

	-- Create Master Key for TDE

	USE master;
	GO
	CREATE MASTER KEY ENCRYPTION
	       BY PASSWORD='QKyrk@%wIj$p97';
	GO

	-- Create Certificate 

	USE master;
	GO
	CREATE CERTIFICATE JB_TDE_Certificate
	       WITH SUBJECT='Certificate for TDE';
	GO

	-- Create Encryption key

	USE JB_DB
	GO
	CREATE DATABASE ENCRYPTION KEY
	WITH ALGORITHM = AES_256
	ENCRYPTION BY SERVER CERTIFICATE JB_TDE_Certificate;  

	-- Enable TDE for database JB_DB

	ALTER DATABASE JB_DB SET ENCRYPTION ON;
	GO

-> Enable TDE for another database.


	--Create database JBS_DB

	create database JBS_DB
	go

        -- Create Encryption key

	USE JBS_DB
	GO
	CREATE DATABASE ENCRYPTION KEY
	WITH ALGORITHM = AES_256
	ENCRYPTION BY SERVER CERTIFICATE JB_TDE_Certificate;  

	-- Enable TDE for database JBS_DB

	ALTER DATABASE JBS_DB SET ENCRYPTION ON;
	GO

-> Execute below query and make sure the databases are encrypted.

select DB_NAME(database_id) AS DatabaseName, encryption_state,
encryption_state_desc =
CASE encryption_state
       WHEN '0' THEN 'No database encryption key present, no encryption'
	   WHEN '1' THEN 'Unencrypted'
	   WHEN '2' THEN 'Encryption in progress'
	   WHEN '3' THEN 'Encrypted'
	   WHEN '4' THEN 'Key change in progress'
	   WHEN '5' THEN 'Decryption in progress'
	   WHEN '6' THEN 'Protection change in progress (The certificate or asymmetric key that is encrypting the database is encrypting the database encryption key is being changed.)'
	   ELSE 'No Status'
	   END,
	   percent_complete,encryptor_thumbprint,encryptor_type
 from sys.dm_database_encryption_keys

-> This is what I see,

Encrypt_DB.PNG

Backup the Certificate and Private Key

USE master;
GO
BACKUP CERTIFICATE JB_TDE_Certificate
TO FILE = 'C:\temp\JB_TDE_Certificate.cer'
WITH PRIVATE KEY (file='C:\temp\JB_TDE_Certificate.pvk',
ENCRYPTION BY PASSWORD='QKyrk@%wIj$p97');

Create certificate on JBSERVER2

-> Copy certificate C:\temp\JB_TDE_Certificate.cer and private key C:\temp\JB_TDE_Certificate.pvk from JBSERVER1 to JBSERVER2.

-> Execute below on JBSERVER2.

USE master;
GO
CREATE MASTER KEY ENCRYPTION
       BY PASSWORD='QKyrk@%wIj$p97';
GO

CREATE CERTIFICATE JB_TD_Certificate
FROM FILE='C:\temp\JB_TDE_Certificate.cer'
WITH PRIVATE KEY (
FILE = 'C:\temp\JB_TDE_Certificate.pvk',
DECRYPTION BY PASSWORD='QKyrk@%wIj$p97')

-> Backup a database from JBSERVER1 and Restore it in JBSERVER2 and make sure restore works.

Adding Database JB_DB and JBS_DB to an Existing Alwayson Availability group JB_AG

-> Perform a Full database backup of JB_DB and JBS_DB on JBSERVER1.

-> Perform a Transaction Log backup of JB_DB and JBS_DB on JBSERVER1.

-> Try adding databases JB_DB and JBS_DB to Availability group JB_AG using GUI.

Add_DB.PNG

-> Adding a TDE enabled database using GUI is not possible. We need to use TSQL.

-> Create a database called Test and make sure it is not enabled with TDE. Create availability group JB_AG using database Test. Once the Availability group JB_AG is created on JBSERVER1 and JBSERVER2, Remove Test database from Availability group and delete the database Test from JBSERVER1 and JBSERVER2. This step is to create JB_AG Availability group before performing below steps.

-> Execute below query on JBSERVER1.

USE master
GO
ALTER AVAILABILITY GROUP [JB_AG] ADD DATABASE [JB_DB]

USE master
GO
ALTER AVAILABILITY GROUP [JB_AG] ADD DATABASE [JBS_DB]

-> Restore Full database backup and Transaction Log backup with NO RECOVERY on JBSERVER2.

-> Execute below query on JBSERVER2 to join the databases JB_DB and JBS_DB to Always On availability group JB_AG


USE master
GO
ALTER DATABASE [JB_DB] SET HADR AVAILABILITY GROUP = [JB_AG];

USE master
GO
ALTER DATABASE [JBS_DB] SET HADR AVAILABILITY GROUP = [JB_AG];

-> Check if the databases are added to Availability group JB_AG.

Thank You,
Vivek Janakiraman

Disclaimer:
The views expressed on this blog are mine alone and do not reflect the views of my company or anyone else. All postings on this blog are provided “AS IS” with no warranties, and confers no rights.